Packlinie mit zwei Zebra ZE500 Druckern

Diese Doku beschreibt einen konkretes Beispiel an einer Fleisch-Packlinie. In anderen Fällen kommt vielleicht nur ein Drucker zum Einsatz und die Etiketten sind anders. Verwenden sie diese Anleitung dann als grobe Richtlinie und passen sie die Details für sich an.

An der Packlinie kommen zwei Zebra ZE500 Druckermodule zum Einsatz, einer für die Etikette oben auf dem Paket und einer für die Etikette unten auf dem Paket.

Seitens BPS werden die Drucker per «Generischer Auszeichner» angesteuert, und die erforderlichen Lade- resp. Druckbefehle werden dort in der ZPL II Pro-grammiersprache von Zebra gespeichert.

Der Generische Auszeichner wurde mit BPS 2.23.2.5 erweitert um 2 unabhängige Drucker gleichzeitig bedienen zu können. Zudem wurde ein neuer Ersetzungsmodus «ZPL» eingeführt, damit die in der Programmiersprache verwendeten Steuerzeichen ^ ~ und _ bei Platzhalter-Texten automatisch durch Hex-Sequenzen ersetzt werden.

BPS sendet beim Aufruf des Artikels die Druckbefehle an die Drucker womit das erste Etikett gedruckt wird. Danach übernimmt es die Steuerung der Packlinie jeweils eine neue Etikette per Impuls an der Applikator-Schnittstelle anzufordern. Ohne weitere Interaktion mit BPS wird so jeweils eine Etikette beim Durchlauf eines Pakets nachgedruckt.

Verwendet werden Druckmodule Typ ZE500-4. Für die Programmierung sind folgende Spezifikationen hauptsächlich massgebend:

• Auflösung 300dpi
• Maximale Druckbreite 104mm resp. 1228 Punkte
• 12 Punkte/mm für Positionsberechnungen
• Firmware Release ist V53.17.22Z

Zur Programmierung in ZPL ist folgendes wissenswert:

• Der interne Flash-Speicher ist 64 MB gross und wird in ZPL als Laufwerk E: angesprochen.
• Grafiken sind vorgängig per «Zebra Font Downloader» im Flash-Speicher zu speichern.
• Die Dateinamen folgen den alten DOS Konventionen, also 8 ASCII Zeichen als Name, plus Erweiterung GRF. Die Benennung muss also entsprechend eingegrenzt werden, da längere Dateinamen welche sich in den ersten 8 Zeichen nicht unterscheiden sich beim Download auf den Drucker gegenseitig überschreiben.
• Grafiken können nur grob in ganzen Faktoren skaliert werden, und gar nicht gedreht werden. Für im Querformat gedruckte Etiketten wie die Untere müssen die Grafiken also vor dem Download auf den Drucker in die richtige Position gedreht werden.

Vollständiges Datenblatt

Für ein optimales Druckergebnis ist es wichtig dass die Papierführung korrekt ist. Alle Etiketten wurden so entwickelt dass der Abstand des Trägerpapiers zum Ende der Abreisskante ca. 1.5mm beträgt, respektive das Trägerpapier bündig mit der darunter liegenden weissen Transportwalze abschliesst.

Ist die Papierzuführung von hinten in den Drucker schief, so kann das Papier mit der Zeit ebenfalls schief laufen. Der Abstand von ca. 1.5 mm wird dann kontinuierlich grösser oder kleiner.

Genauso wichtig für die gerade Papierführung ist der gleichmässige Andruck an die weisse Transportwalze. Dieser wird durch die beiden Walzenandruckstössel realisiert, und kann mit den Rändelschrauben korrigiert werden. Verstellen sie nicht zu viel auf einmal, z.B. eine Viertelumdrehung auf einer Seite und beobachten sie etwa 10 Etiketten lang ob es besser oder schlechter wird. Behalten sie dabei auch die Schwärzung im Auge.

Zur Verfügung stehen folgende Selbstklebe-Etiketten auf Trägermaterial, jeweils aussen gerollt:

Vorgedruckte Etiketten mit einer Breite von 68mm und einer Länge von 46mm. Der Abstand zweier Etiketten auf dem Trägerband beträgt 3mm und das Trägerband ist 71.5mm breit.

Der Vordruck im Beispiel ist ein Schweizerkreuz oben rechts für Schweizer Fleisch, und ein MIGROS Schriftzug unten rechts. Auf Grund der Druckrichtung müssen Texte und Grafiken beim Drucken um 180° gedreht werden.

Diese Etiketten werden oben auf der Verpackung angebracht.

Vorgedruckte Etiketten mit einer Breite von 68mm und einer Länge von 60mm. Der Abstand zweier Etiketten auf dem Trägerband beträgt 3.5mm und das Trägerband ist 75mm breit.

Der Vordruck ist ähnlich dem vorgängigen, einfach ist oben noch ein zusätzlicher Bereich von 14mm mit AKTION. Im Beispiel ist noch ein GGA Zertifikats-Logo der St.Galler Kalbsbratwurst vorgedruckt.

Aus Programmiersicht ist diese Etikette sehr ähnlich wie die erste, allerdings sind alle Druckobjekte verschoben.

Weisse Etiketten mit einer Breite von 100mm und einer Länge von 65mm. Der Abstand zweier Etiketten auf dem Trägerband beträgt 4mm und das Trägerband ist 105mm breit.

Diese werden als untere Etikette verwendet, wobei die Texte und Grafiken beim Drucken um 90° nach rechts gedreht sind.

Auch der EAN13 Barcode der auf diesen unteren Etiketten gedruckt wird ist gedreht, was für die Codequalität ungünstig ist (Verschmiereffekt). Dem muss man durch Einschränkung der Druckgeschwindigkeit und der Thermo-Temperatur Rechnung tragen:

Dies sind die Einstellungen die während der Entwicklung der Etikettenlayouts verwendet wurden. An der Packlinie müssen einzelne Parameter natürlich nach aktuellem Bedarf angepasst werden, insbesondere natürlich die Netzwerkadresse, Schwärzung und Druckgeschwindigkeit sowie die Steuerung per Applikator-Port:

Zu beachten ist, dass der Drucker nur Dateinamen nach DOS-Konvention spei-chern kann, also einen Namensteil aus maximal 8 ASCII Zeichen und eine DateinamenErweiterung aus maximal 3 ASCII Zeichen.

Die Dateinamen sollten deshalb bereits auf dem PC auf maximal 8 Zeichen ge-kürzt werden. Für unseren Zweck habe ich maximal 7 Zeichen zur Beschreibung des Inhalts verwendet und 1 Zeichen als Variante-Nummer.

Die Grafiken liegen typischerweise auf dem PC als GIF oder JPG Dateien vor. Beim Download der Grafiken auf den ZE500 werden diese durch den «Zebra Font Downloader» automatisch in GRF Dateien umgewandelt, wie vom Drucker benötigt.

Der Font Downloader ist in den «Zebra Setup Utilities» integriert. Sie benötigen diese Programme jedoch nur um die Grafiken auf den Drucker zu laden (oder ggf. zusätzliche Schriften). Diese Software wird typischerweise auf einem Support-PC oder –Laptop installiert, auf dem PC der Packlinie braucht man diese jedoch nicht.

Laden sie die aktuelle Version der Zebra Setup Utilities von der Zebra Website für ihr Betriebssystem herunter:

Starten sie das Installationsprogramm und führen den Setup durch:

Schalten sie vor dem ersten Start den Drucker ein, verbinden sie ihn mit dem LAN und stellen sie die IP Parameter ein (siehe Beispielkonfiguration in Kapitel 4, Setup ZE500).

Beim ersten Start werden automatisch die Druckertreiber installiert:

Wählen sie dann die die TCP-IP Schnittstelle:

Jetzt übernimmt die standardmässige Windows Druckerinstallation:

Wählen sie den passenden Druckertyp aus, den ZE500-4 in rechtsseitiger Ausführung (RH) mit 300dpi Druckleiste:

Fügen sie dann einen TCP-IP Port mit der Adresse des Druckers hinzu:

Wählen sie, dass der «Zebra Font Downloader» auch installiert wird:

Den «Zebra Status Monitor» benötigen wir hingegen nicht.

Nach Komplettierung der Einrichtung der Setup Utilities sowie Installation des Font Downloaders wird der eingerichtete Drucker aufgelistet:

Sie können nun noch den zweiten Drucker für die untere Etikette analog hinzufügen.

Das Programm kann unter anderem verwendet werden um den Drucker zu konfigurieren und Befehle zu senden, was für die Entwicklung komplett neuer Etiketten hilfreich ist. Hier für uns ist vor allem die Downloadfunktion interessant.

Starten sie den Downloader mit dem Button «Download Fonts and Graphics».

Wählen sie «Flash» und klicken sie auf den Button zur Erzeugung eines neuen Flash Speichers:

Wählen sie einen sprechenden Namen für die Datei:

Geben sie eine Beschreibung ein und wählen sie 65536 K Bytes da der Drucker intern einen 64 MB Flash Speicher hat:

Fügen sie das erste Bild hinzu:

Sie können die Grafik nun auch sofort auf den Drucker herunterladen:

Laden sie nun alle benötigten Grafiken in gleicher Weise:

Die Grafiken sind jetzt sowohl in der mmf Datei, als auch im Flash-Speicher des Druckers als GRF Grafiken gespeichert. Die mmf Datei können sie später verwenden um die gleichen Grafiken auch auf weitere Drucker herunterzuladen, oder um neue Grafiken oder Schriften hinzuzufügen.

Die Grafiken wurden von GMOS zur Verfügung gestellt. Grafiken welche auf der unteren Etikette eingesetzt werden sind um 90° nach rechts gedreht.

Zusätzliche Schriften die ebenfalls mit dem «ZebraDesigner Fonts and Graphics Downloader» auf den Drucker geladen werden, müssen vorgängig in Windows installiert sein.

Im Windows Explorer mit der rechten Maustaste auf die Schriftdateien klicken, und danach «Für alle Benutzer installieren»:

Sind die gewünschten Schriften installiert, so können sie anschliessend im «ZebraDesigner Fonts and Graphics Downloader» hinzugefügt werden. Man hat leider keinen direkten Einfluss darauf wie die Schriften auf dem Drucker dann heissen, sie werden vom Downloader selbständig benannt und nummeriert. Deshalb ist die Reihenfolge in der die Schriften hinzugefügt werden entscheidend.

Fügen sie also zuerst die normale Schrift hinzu, und die Fettschrift als zweites:

Nachher sollten die Schriften in der korrekten Reihenfolge sein, also zuerst die normale Schrift und danach die Fettschrift:

Die normale Schrift wird auf dem Drucker unter E:MIG000.FNT gespeichert, und die fette unter E:MIG001.FNT.

Die heruntergeladenen Migros-Schriften werden verwendet. Sie werden deshalb zu Beginn mittels CW Befehlen den Schriften A8 und A9 zugeordnet.

Da die Etikette mit dem Kopf voraus aus dem Drucker kommt, muss der ganze Druck mit dem Befehl ^POI um 180° gedreht werden. Der Ursprung 0/0 wandert dabei aus Etikettensicht von unten rechts nach oben links.

Mit ^FWN wird definiert, dass die Felder standardmässig in Normalrichtung geduckt werden. Das ist wichtig falls vorher eine Etikette mit rotierten Feldern gedruckt wurde wo ein anderer ^FW Befehl gültig war, z.B. bei der unteren Etikette.

Mit ^CI28 wird der Zeichensatz UTF-8 gewählt, in der Packlinienkonfiguration ist «UTF-8 ohne BOM» einzustellen. Damit ist sichergestellt dass Umlaute und andere Zeichen ausserhalb des ASCII Zeichensatzes immer korrekt gedruckt werden.

Bei Feldern mit Platzhaltern die freien Text enthalten ist jeweils ^FH vor dem ^FD um die Hex-Decodierung zu aktivieren. In der Packlinienkonfiguration ist ent-sprechend der Ersetzungsmodus «ZPL» einzustellen um die Hex-Codierung der Zeichen ^ ~ und _ einzustellen. Ohne diese Einstellungen gibt er Fehler wenn eines dieser Zeichen im Text vorkommt. Bei Platzhaltern welche keines dieser Sonderzeichen enthalten können (z.B. Datum, Zahlen) ist das Voranstellen von ^FH nicht erforderlich.

Beim Platzhalter t_animal_pictogramm wird fix E: für das interne Flash-Laufwerk vorangestellt, sowie .GRF als Dateinamenserweiterung angehängt. Im entspre-chenden Feld des Artikels muss deshalb nur der Name der Datei ohne Erweite-rung angegeben werden, im Beispiel «SCHWKAL1». Soll kein Tier-Piktogramm ge-druckt werden, so lässt man das Feld einfach leer oder kann das Feld im Artikel auch ganz weglassen.

Druckbefehle:

^XA
^CW8,E:MIG000.FNT
^CW9,E:MIG001.FNT
^POI
^FWN
^CI28
^FO370,270^IME:[t_animal_pictogram].GRF^FS
^FO45,640^IME:MTEMP501.GRF^FS
^FO50,400^AU^FH^FD[t_name_de]^FS
^FO50,460^AT^FH^FD[t_name_it]^FS
^FO56,524^AR^FDFr./kg^FS
^FO50,560^AU^FD[x_cpr_kg:decimals=2]^FS
^FO290,550^AV^FD[a_kg_cu:decimals=3] kg^FS
^FO410,524^AR^FB310,,,R^FDFr.^FS
^FO410,560^AV^FB380,,,R^FD[x_cpr_cu:decimals=2]^FS
^FO190,650^A8,22,30^FH^FDVerkaufen bis / [t_text_to_sell_by]^FS
^FO190,680^A8,22,30^FH^FDVerbrauchen bis^FS
^FO190,700^A8,22,30^FH^FD[t_text_to_use_up]^FS
^FO410,648^AS^FB380,,,R^FD[x_selldate:format=dd.MM.yy]^FS
^FO410,690^AS^FB380,,,R^FD[x_expiredate:format=dd.MM.yy]^FS
^XZ

Die Etikette ist weitgehend identisch mit der vorgängigen Aktionsetikette. Da der Aktionskopf fehlt sind alle Y-Kooridinaten um ca. 170 Punkte reduziert, und da der linke Rand auf Grund des schmaleren Trägerpapiers auch kleiner ist sind die X-Koordinaten auch etwas kleiner.

Druckbefehle:

^XA
^CW8,E:MIG000.FNT
^CW9,E:MIG001.FNT
^POI
^FWN
^CI28
^FO370,80^IME:[t_animal_pictogram].GRF^FS
^FO10,450^IME:MTEMP501.GRF^FS
^FO10,210^AU^FH^FD[t_name_de]^FS
^FO10,270^AT^FH^FD[t_name_it]^FS
^FO16,334^AR^FDFr./kg^FS
^FO10,370^AU^FD[x_cpr_kg:decimals=2]^FS
^FO250,360^AV^FD[a_kg_cu:decimals=3] kg^FS
^FO370,334^AR^FB310,,,R^FDFr.^FS
^FO370,370^AV^FB380,,,R^FD[x_cpr_cu:decimals=2]^FS
^FO150,460^A8,22,30^FH^FDVerkaufen bis / [t_text_to_sell_by]^FS
^FO150,490^A8,22,30^FH^FDVerbrauchen bis^FS
^FO150,510^A8,22,30^FH^FD[t_text_to_use_up]^FS
^FO370,458^AS^FB380,,,R^FD[x_selldate:format=dd.MM.yy]^FS
^FO370,500^AS^FB380,,,R^FD[x_expiredate:format=dd.MM.yy]^FS
^XZ

Gegenüber den beiden oberen Etiketten wird die untere Etikette um 90° gedreht gedruckt. Der ZPL Befehl ^PO kann dazu nicht verwendet werden da er nur normal oder um 180° gedreht unterstützt. Der Befehl ^PON wird aber als erstes gesendet um zunächst wieder die Normalrichtung einzustellen, falls vorher der invertierte Druck aktiv war.

Alle nachfolgenden Text- und Barcodefelder werden durch den Befehl ^FWR um 90° gedreht. Auf Grafiken wirkt dieser Befehl nicht, deshalb müssen die auf dieser Etikette verwendeten Grafiken bereits um 90° gedreht vorhanden sein.

Druckbefehle:

^XA
^CW8,E:MIG000.FNT
^CW9,E:MIG001.FNT
^PON
^FWR
^CI28
^FO380,0^IME:NAEHRWE5.GRF^FS
^FO330,700^IME:ABFALL5.GRF^FS
^FO150,8^IME:MINFOLI5.GRF^FS
^FO1180,8^A8,30,30^FH^FD[t_produced_de]^FS
^FO1140,8^A9,30,30^FH^FD[t_subtitle_de]^FS
^FO1110,8^A9,30,30^FH^FD[t_subtitle_it]^FS
^FO1070,8^A8,24,24^FH^FD{a}[t_ingredients_de:maxchars=80,maxlines=1]{/a}^FS
^FO1046,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO1022,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO998,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO974,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO950,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO926,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO902,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO878,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO854,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO830,8^A8,24,24^FH^FD{a}[t_ingredients_de:continue,maxchars=80,maxlines=1]{/a}^FS
^FO786,8^A8,24,24^FH^FD{a}[t_ingredients_it:maxchars=80,maxlines=1]{/a}^FS
^FO762,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO738,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO714,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO690,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO666,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO642,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO618,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO594,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO570,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO546,8^A8,24,24^FH^FD{a}[t_ingredients_it:continue,maxchars=80,maxlines=1]{/a}^FS
^FO490,8^A8,22,22^FB352,,,R^FD100g^FS
^FO454,8^A8,22,22^FB352,,,R^FD[t_100_energy_kj]kj([t_100_energy_kcal]kcal)^FS
^FO432,8^A8,22,22^FB356,,,R^FD[t_100_fat_g]g^FS
^FO392,8^A8,22,22^FB356,,,R^FD[t_100_fattyacids_g]g^FS
^FO500,394^A8,22,22^FB352,,,R^FD[t_100_carbohydrate_g]g^FS
^FO480,394^A8,22,22^FB352,,,R^FD[t_100_sugar_g]g^FS
^FO456,394^A8,22,22^FB352,,,R^FD[t_100_roughage_g]g^FS
^FO432,394^A8,22,22^FB352,,,R^FD[t_100_protein_g]g^FS
^FO408,394^A8,22,22^FB352,,,R^FD[t_100_sel_g]g^FS
^FO340,8^A9,24,24^FH^FD[t_package_de]^FS
^FO310,8^A9,24,24^FH^FD[t_package_fr_it]^FS
^FO318,470^GE48,192,2^FS
^FO328,395^A8,26,24^FB352,,,C^FD[t_producer_no]^FS
^FO250,8^A8,22,30^FDVertrieb/Distribuzione^FS
^FO228,8^A8,22,30^FDMigros Ostschweiz^FS
^FO206,8^A8,22,30^FDCH-9201 Gossau^FS
^FO198,450^BY3^BER,86,Y,N^FD[a_barcode]^FS
^FO110,8^A8,24,24^FH^FDL[x_lot]^FS
^FO110,270^A8,24,24^FDCode14^FS
^FO110,490^A8,34,34^FH^FD[a_id]^FS
^XZ

Zu beachten ist, dass die Inhaltsstoffe nicht im Block gedruckt werden können falls man Allergene fett hervorheben möchte. Dazu muss nämlich ein Trick angewendet werden wo das aktuelle Druckfeld vor dem Allergen beendet wird und ein neues Druckfeld in fetter Schrift begonnen wird. Umgekehrt dann wieder nach dem Allergen um wieder zur normalen Schrift zurückzukehren. Ein Text mit Allergenen erscheint also für den Drucker als eine Abfolge von mehreren Textfeldern, und das kann von ihm nicht korrekt als Block formatiert werden.

Aus diesem Grund werden die Inhaltsstoffe hier pro Sprache als maximal je 11 einzelne Zeilen generiert. Die maximale Anzahl Zeichen pro Zeile hängt von der Schriftbreite ab. Bei Schriftbreite 24 scheinen mir 80 Zeichen pro Zeile ein guter Wert, bei breiterer oder schmalerer Schrift müsste das natürlich angepasst werden.

Da die verwendeten Migros-Schriften proportional sind, ist die Anzahl Zeichen pro Zeile keine exakte Angabe sondern ein Durchschnittswert. Im Extremfall kann es daher passieren dass die gedruckte Zeile zu lang wird (viele breite Buchstaben), oder umgekehrt ein Wort bereits auf die nächste Zeile kommt obwohl es eigentlich noch auf die vorherige gepasst hätte (viele schmale Buchstaben).

Anhand der von GMOS gelieferten Etiketten-Muster wurden zwei Basis-Auszeichnereinstellungen entwickelt:

• ZE500 68×46 CH:
  • Oben: siehe Etikette oben, 68×46 mit Schweizerkreuz
  • Unten: siehe Etikette unten, 100×65
• ZE500 68×60 CH GGA Aktion:
  • Oben: siehe Etikette oben, 68×60 mit Aktion, GGA Logo, Schweizerkreuz
  • Unten: siehe Etikette unten, 100×65

Ausgehend von diesen beiden Vorlagen können sehr einfach weitere Varianten erstellt werden, z.B. mit dem Tier-Piktogramm an anderer Stelle, oder ohne die italienischen Texte.

Die neuen Auszeichnereinstellungen werden einfach mit der entsprechenden Funktion hinzugefügt, der Generische Auszeichner ausgewählt und der Name der Auszeichnereinstellung eingegeben:

Als Typ wird z.B. «ZE500 Dual» eingegeben.

Die Druckbefehle für obere und untere Etikette werden per Copy/Paste in die Eingabebereiche der Ladebefehle von Drucker 1 und Drucker 2 eingefügt:

Mit dem Testprogramm in den Auszeichnereinstellungen können Anpassungen getestet werden, ohne dass extra eine Packlinienkonfiguration vorgenommen werden muss. Füllen sie einfach die Eingabefelder wie oben und passen sie nach Bedarf Adresse, Artikel usw. an.

Wenn sie nur einen Testdrucker haben, können sie den zweiten ausschalten indem sie dort bei Schnittstelle statt «Netzwerk TCP/IP» einfach «Nicht vorhan-den» einstellen. So können sie die untere und obere Etikette einzeln testen.

Nachdem die Einstellungen gemacht sind, wird zuerst Button «Auszeichner öffnen» betätigt und danach «Artikel senden». Jetzt müsste die Etikette gedruckt werden, falls der Drucker richtig konfiguriert ist und im Display steht «Drucker bereit».

Mit «Auszeichner schliessen» und «Exit» kehren sie zu den Auszeichnereinstellungen zurück um allfällige Korrekturen vorzunehmen.

Damit die Allergene auf der unteren Etikette fett erscheinen, müssen die entsprechenden Umschaltbefehle für die Hervorhebung beim Drucker 2 eingegeben werden:

Zu Beginn der Hervorhebung: ^FS^FT^A9,24,24^FH^FD

Das Ende der Hervorhebung ist im Grunde dasselbe, einfach wird jetzt wieder mit der normalen Schrift A8 statt A9 weitergedruckt:

^FS^FT^A8,24,24^FH^FD

Es ergibt sich daraus, dass man die Hervorhebung so nur für eine bestimmte Schriftgrösse machen kann. In der Praxis ist das kein Problem, da man die Allergene nur in den Inhaltsstoffen hervorheben will, und es keinen plausiblen Grund gibt diese in unterschiedlichen Grössen zu drucken.

Die Einstellungen der beiden Drucker sind analog dem Testprogramm im voran-gehenden Kapitel. Bei Drucker 2 ist typischerweise die IP Adresse unterschiedlich einzustellen, und die Umschaltbefehle für die Hervorhebung sind dort einzugeben.

Wichtig ist, dass der Typ analog zu den Auszeichnereinstellungen eingegeben wird, im Beispiel also «ZE500 Dual»

Auch hier steht ein Testprogramm zur Verfügung um die Einstellungen zu kontrollieren.

Stellen sie bei «Verpackung» die gewünschten Auszeichnereinstellungen für Normalpreis und Aktion ein. Die Einstellungen für Einführungspreis und Aus-verkaufspreis sind optional falls sie diese Preiscodes in der Praxis nicht verwenden.

Kontrollieren Sie ob die in den Auszeichnereinstellungen verwendeten Texte und Artikelfelder vorhanden und korrekt ausgefüllt sind:

Auch hier im Artikelstamm steht wieder ein Testprogramm zur Verfügung mit welchem sie den Etikettendruck des bearbeiteten Artikels sehr einfach kontrollieren können.

Funktioniert soweit alles, dann wird es auch beim Abpacken im Packlinienprogramm funktionieren.